allprojects {
    group 'de.exlll'
    version '2.2.0'
}
subprojects {
    apply plugin: 'java'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    repositories { mavenCentral() }

    dependencies {
        testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-api', version: '5.0.3'
        testImplementation group: 'org.junit.platform', name: 'junit-platform-runner', version: '1.0.3'
        testImplementation group: 'org.junit.platform', name: 'junit-platform-suite-api', version: '1.0.3'
        testImplementation group: 'org.hamcrest', name: 'hamcrest-all', version: '1.3'
        testImplementation group: 'com.google.jimfs', name: 'jimfs', version: '1.1'
    }
}
buildscript {
    if (project.hasProperty("local_script")) {
        apply from: file(local_script + "/buildscript.gradle"), to: buildscript
    }
}
if (project.hasProperty("local_script")) {
    apply from: file(local_script + "/build.gradle")
}

project(':configlib-core') {
    dependencies { implementation group: 'org.yaml', name: 'snakeyaml', version: '1.20' }
}
project(':configlib-bukkit') {
    repositories { maven { url 'https://hub.spigotmc.org/nexus/content/repositories/snapshots/' } }
    dependencies {
        implementation project(':configlib-core')
        implementation group: 'org.bukkit', name: 'bukkit', version: '1.12.2-R0.1-SNAPSHOT'
    }
    jar { from { project(':configlib-core').sourceSets.main.output } }
}
project(':configlib-bungee') {
    repositories { maven { url 'https://oss.sonatype.org/content/repositories/snapshots' } }
    dependencies {
        implementation project(':configlib-core')
        implementation group: 'net.md-5', name: 'bungeecord-api', version: '1.12-SNAPSHOT'
    }
    jar { from { project(':configlib-core').sourceSets.main.output } }
}