PagineDown/build.gradle

plugins {
    id 'org.cadixdev.licenser' version '0.6.1'
    id 'maven-publish'
    id 'java'
}

group 'net.william278'
version '1.1'
defaultTasks 'licenseFormat', 'build'

repositories {
    mavenCentral()
    maven { url 'https://repo.minebench.de/' }
}

dependencies {
    compileOnly 'de.themoep:minedown-adventure:1.7.1-SNAPSHOT'
    compileOnly 'org.jetbrains:annotations:24.0.1'

    testImplementation 'de.themoep:minedown-adventure:1.7.1-SNAPSHOT'
    testImplementation 'net.kyori:adventure-platform-bukkit:4.3.0'
    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.9.3'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.9.3'
}

compileJava.options.encoding = 'UTF-8'

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
}

logger.lifecycle("Building PagineDown ${version} by William278")
version rootProject.version
archivesBaseName = "${rootProject.name}"

license {
    header = rootProject.file('HEADER')
    include '**/*.java'
    newLine = true
}

javadoc {
    options.encoding = 'UTF-8'
    options.addStringOption('Xdoclint:none', '-quiet')
}

java {
    withSourcesJar()
    withJavadocJar()
}

publishing {
    publications {
        shadow(MavenPublication) { publication ->
            from components.java
        }
    }
    repositories {
        mavenLocal()
    }
}

test {
    useJUnitPlatform()
}